//  Dépouillement d'une rosette d'extensométrie

//  Yves DEBARD - 14 octobre 2009

//  Institut Universitaire de Technologie du MANS
//  Département Génie Mécanique et Productique
//  Avenue Olivier Messiaen
//  72085 LE MANS CEDEX 9

//  Scilab 4.1.2

// ======================================================

// angle de la rosette en degrés

phi=45

// matériau

E=210000     // module de Young
nu=0.27      // coefficient de Poisson

// allongements unitaires mesurés

Ea=-100E-6
Eb=-450E-6
Ec=400E-6

// calcul des déformations Exx , Eyy , Gxy et Ezz
// l'axe x est l'axe de la jauge a

rphi=phi*%pi/180;
c=cos(rphi);s=sin(rphi);
Exx=Ea;
Eyy=(-Ea+2*Eb+Ec+2*c^2*Ea-4*c^2*Eb)/(2*s^2);
Gxy=(Ea-Ec-4*c^2*Ea+4*c^2*Eb)/(2*s*c);
Ezz=-nu*(Exx+Eyy)/(1-nu);

// calcul des contraintes Sxx, Syy et Sxy

c=E/(1-nu^2)
Sxx=c*(Exx+nu*Eyy)
Syy=c*(Eyy+nu*Exx)
G=E/2/(1+nu); // module d'élasticité transversal
Sxy=G*Gxy

// tenseur des contraintes

sigma=[Sxx Sxy 0 ; Sxy Syy 0 ; 0 0 0]

// contraintes principales

d=0.5*(Sxx+Syy);
r=0.5*sqrt((Sxx-Syy)^2+4*Sxy^2);
S1=d+r
S2=d-r
S3=0

// angle en degrés de la direction principale n1 avec la jauge a

t1=atan((S1-Sxx)/Sxy)*180/%pi

// tenseur des déformations

epsilon=[Exx,1/2*Gxy,0;1/2*Gxy,Eyy,0;0,0,Ezz]

// déformations principales

E1=(S1-nu*S2)/E
E2=(S2-nu*S1)/E
E3=-nu*(S1+S2)/E

// déformation volumique dV/V

dV_V=trace(epsilon)

// contrainte équivalente de Von Mises

Von_Mises=sqrt(S1^2+S2^2-S1*S2)

// contrainte équivalente de Tresca

Tresca=max(S1,S2,0)-min(S1,S2,0)

// cisaillement maximal

tau_max=0.5*Tresca

// énergie de déformation par unité de volume en MPa

energie=0.5*(Sxx*Exx+Syy*Eyy+Sxy*Gxy)
// ou
energie=0.5*trace(sigma*epsilon)

// énergie de déformation par unité de volume en J/m3

energie=energie*1e6

//   éditions   =====================================================
 
printf('\n\nRosette à %3d degrés\n\n',phi);
printf('Module de Young : %8.0f MPa\n\n',E)
printf('Coefficient de Poisson : %5.2f\n\n',nu)
printf('Mesures : Ea = %5.0f E-6 ,  Eb = %5.0f E-6 ,  Ec = %5.0f E-6\n\n',Ea*1E6,Eb*1E6,Ec*1E6)
printf('Déformations principales : E1 = %5.0f E-6 ,  E2 = %5.0f E-6 ,  E3 = %5.0f E-6\n\n',E1*1E6,E2*1E6,E3*1E6)
printf('Contraintes principales : S1 = %5.2f MPa ,  S2 = %5.2f MPa , S3 = 0\n\n',S1,S2)
printf('Angle de la direction principale n1 avec la jauge a : %5.2f degrés\n\n',t1)

// ==================================================================