====================================================================

  programme Maple  -  14 octobre 2009

  Dépouillement d'une rosette d'extensométrie

     Yves DEBARD

     Institut Universitaire de Technologie du MANS
     Département Génie Mécanique et Productique
     Avenue Olivier Messiaen
     72085 LE MANS CEDEX 9

====================================================================

restart:with(linalg):

# matériau

E:=210000;     # module de Young
nu:=0.27;      # coefficient de Poisson
G:=E/2/(1+nu): # module d'élasticité transversal

# angle de la rosette en degrés

phi:=45;

# allongements unitaires mesurés

ea:=-100E-6;
eb:=-450E-6;
ec:=400E-6;

# allongement unitaire dans la direction théta

epsilon_n:=proc(theta)
    local nx,ny:
    nx:=cos(theta):ny:=sin(theta):
    exx*nx*nx+eyy*ny*ny+gxy*nx*ny:
  end:

# calcul des déformations exx , eyy et gxy
# l'axe x est l'axe de la jauge a

phi:=phi*Pi/180:
fsolve({ea=epsilon_n(0),eb=epsilon_n(phi),ec=epsilon_n(2*phi)},{exx,eyy,gxy}):
assign(%):

# calcul des contraintes et de ezz

c:=E/(1-nu^2):
sxx:=c*(exx+nu*eyy):
syy:=c*(eyy+nu*exx):
sxy:=G*gxy:
ezz:=-nu/E*(sxx+syy):

# tenseur des contraintes

sigma:=matrix(3,3,[[sxx,sxy,0],[sxy,syy,0],[0,0,0]]);

# contraintes principales

d:=0.5*(sxx+syy):r:=0.5*sqrt((sxx-syy)^2+4*sxy^2):
S1:=d+r;S2:=d-r;S3:=0;

# angle en degrés de la direction principale 1 avec la jauge a

t1:=evalf(arctan((S1-sxx)/sxy)*180/Pi);

# tenseur des déformations

epsilon:=matrix(3,3,[[exx,1/2*gxy,0],[1/2*gxy,eyy,0],[0,0,ezz]]);

# déformations principales

E1:=(S1-nu*S2)/E;
E2:=(S2-nu*S1)/E;
E3:=ezz;

# déformation volumique dV/V

dV_V:=trace(epsilon);

# contrainte équivalente de Von Mises

Von_Mises:=sqrt(S1^2+S2^2-S1*S2);

# contrainte équivalente de Tresca

Tresca:=max(S1,S2,0)-min(S1,S2,0);

# cisaillement maximal

tau_max:=0.5*Tresca;

# énergie de déformation par unité de volume en MPa

energie:=0.5*(sxx*exx+syy*eyy+sxy*gxy);
# ou
energie:=0.5*trace(multiply(sigma,epsilon));