====================================================================

  programmes Maple  -  24 mars 2006 - 9 novembre 2006

  Méthodes énergétiques : théorème de Castigliano

     Yves DEBARD

     Institut Universitaire de Technologie du MANS
     Département Génie Mécanique et Productique
     Avenue Olivier Messiaen
     72085 LE MANS CEDEX 9

====================================================================

# Exercice 1 : poutre console soumise à un effort normal

# initialisation

restart:

# effort normal dans la section d'abscisse x

N:=F+q*(L-x);

# énergie de déformation

dEdef:=N^2/(2*E*A);
Edef:=int(dEdef,x=0..L);

# déplacement du noeud 2

u2:=simplify(diff(Edef,F));

# déplacement de la section d'abscisse x

N0_x:=F+q*(L-s)+Q;
Nx_L:=F+q*(L-s);

Edef:=int(N0_x^2,s=0..x)+int(Nx_L^2,s=x..L):
Edef:=simplify(Edef/(2*E*A));

ux:=diff(Edef,Q);

ux:=subs(Q=0,ux);

u2:=simplify(subs(x=L,ux));

-------------------------------------------------------------


# Exercice 2 : 

# poutre console sollicitée en flexion simple
# influence de l'effort tranchant

restart: # initialisation

# efforts dans la section d'abscisse x

Ty:=F;
Mfz:=F*(L-x);

# énergie de déformation

ET:=int(Ty^2/(2*G*A*ky),x=0..L);
EMfz:=int(Mfz^2/(2*E*Iz),x=0..L);
Edef:=ET+EMfz;

# déplacements du noeud 2

v2T:=diff(ET,F);v2:=diff(Edef,F);

# influence de l'effort tranchant

M:=0;

G:=E/2/(1+nu);
ky:=10*(1+nu)/(12+11*nu);
plot(ky,nu=0..0.5,title="ky=10*(1+nu)/(12+11*nu)");
A:=b*h:
Iz:=b*h^3/12:

L:=x*h:

f:=simplify(v2T/v2);

f1:=subs(nu=0,f);f2:=subs(nu=0.25,f);f3:=subs(nu=0.5,f);
plot([f1*100,f2*100,f3*100],x=3..20,
    legend=["nu=0","nu=0.25","nu=0.5"],
    title="Influence de l'effort tranchant en % en fonction du coefficient de Poisson",
    labels=["L / h","v2T/v2 en %"],
    color=[black,red,green],thickness=2);


---------------------------------------------------------------

# Exercice 3 : 

# poutre console sollicitée en flexion simple
# matrice de rigidité

# initialisation

restart:with(linalg):

# efforts dans la section d'abscisse x

Ty:=F+p*(L-x);
Mfz:=M+F*(L-x);

# énergie de déformation

dEdef:=Ty^2/(2*G*A*ky)+Mfz^2/(2*E*Iz);
Edef:=int(dEdef,x=0..L);

# déplacements du noeud 2

u2:=grad(Edef,[F,M]);simplify(u2);

# matrice de souplesse

C:=hessian(Edef,[F,M]);
# ou
C:=jacobian(u2,[F,M]);

# matrice de rigidité

K:=inverse(C);

--------------------------------------------------------------


# Exercice 4 : poutre console sollicitée en flexion simple

restart: # initialisation

# efforts dans la section d'abscisse x

Ty:=F+q*(L-x);
Mfz:=M+F*(L-x)+q*(L-x)^2/2;

# énergie de déformation

ET:=int(Ty^2/(2*G*A*ky),x=0..L);
EMfz:=int(Mfz^2/(2*E*Iz),x=0..L);
Edef:=ET+EMfz;

# déplacements du noeud 2

v2T:=diff(ET,F);v2:=diff(Edef,F);
rotz2T:=diff(ET,M);rotz2:=diff(Edef,M);
F:=0;M:=0;
v2;rotz2;

# influence de l'effort tranchant

G:=E/2/(1+nu);
ky:=10*(1+nu)/(12+11*nu);
A:=b*h:
Iz:=b*h^3/12:

L:=x*h:

f:=simplify(v2T/v2);

f1:=subs(nu=0,f);f2:=subs(nu=0.25,f);f3:=subs(nu=0.5,f);
plot([f1*100,f2*100,f3*100],x=3..20,
    legend=["nu=0","nu=0.25","nu=0.5"],
    title="Influence de l'effort tranchant en % en fonction du coefficient de Poisson",
    labels=["L / h","v2T/v2 en %"],
    color=[black,red,green],thickness=2);



--------------------------------------------------------------

# Exercice 5 : étude d'un arc plan

restart: # initialisation de la mémoire

with(linalg):  # librairie de calcul matriciel

angle_arc:=3*Pi/2;

# efforts dans la section phi

c:=cos(phi):s:=sin(phi):

N:=Fx*s-Fy*c;
T:=Fx*c+Fy*s;
Mfz:=(Fx*s+Fy*(1-c))*R+Mz;

# énergie de déformation

EN:=int(N^2/(2*E*A)*R,phi=0..angle_arc);
ET:=int(T^2/(2*G*k*A)*R,phi=0..angle_arc);
EMfz:=int(Mfz^2/(2*E*Iz)*R,phi=0..angle_arc);
Edef:=EN+ET+EMfz;

# déplacement

u2:=diff(Edef,Fx);

v2:=diff(Edef,Fy);

rotz2:=diff(Edef,Mz);


--------------------------------------------------------------

# Exercice 6 : étude d'un arc plan

# initialisation

restart:

# angle de l'arc

angle_arc:=3*Pi/2;

# efforts dans la section théta

N:=F*sin(phi);
T:=F*cos(phi);
Mfz:=F*R*sin(phi);

# énergie de déformation

EN:=int(N^2/(2*E*A)*R,phi=0..angle_arc);
ET:=int(T^2/(2*G*k*A)*R,phi=0..angle_arc);
EMfz:=int(Mfz^2/(2*E*Iz)*R,phi=0..angle_arc);
Edef:=EN+ET+EMfz;

# déplacement

vN:=diff(EN,F);
vT:=diff(ET,F);
vMfz:=diff(EMfz,F);

v:=vN+vT+vMfz;

# influence de l'effort normal et de l'effort tranchant

G:=E/2/(1+nu);
k:=5/6;
#k:=10*(1+nu)/(12+11*nu);
A:=b*h:
Iz:=b*h^3/12:

R:=x*h:

fnor:=simplify(vN/v);
ftra:=simplify(vT/v);

f1:=subs(nu=0,ftra);f2:=subs(nu=0.25,ftra);f3:=subs(nu=0.5,ftra);
plot([f1*100,f2*100,f3*100],x=2..10,
    legend=["nu=0","nu=0.25","nu=0.5"],
    title="Influence de l'effort tranchant en % en fonction du coefficient de Poisson",
    labels=["R / h","vT/v en %"],
    color=[black,red,green],thickness=2);

nu:=0.25;

plot([fnor*100,ftra*100],x=2..10,
   legend=["effort normal","effort tranchant"],
   title="Influence de l'effort normal et de l'effort tranchant en % (nu=0.25)",
   labels=["R / h",""],
   thickness=2);

-------------------------------------------------